Análisis Factorial con Modelo COSAN y Restricciones (PROC CALIS)

Nivel de dificultad

Principiante

Publicado el : 13/11/2021

Este script utiliza el procedimiento CALIS para analizar una matriz de correlación (datos de Kinzer & Kinzer, Guttman 1957). Define un modelo tipo COSAN especificando explícitamente las matrices de parámetros (D, B, Psi) y aplica restricciones algebraicas complejas sobre las cargas factoriales y las estructuras de correlación usando instrucciones de programación SAS^© integradas.

Análisis de datos

Type : CREATION_INTERNE

Los datos son una matriz de correlación (TYPE=CORR) creada directamente en el script a través de un DATA STEP y datalines.

1 Bloque de código

DATA STEP Data

Explicación :
Creación del conjunto de datos 'kinzer' que contiene la matriz de correlación triangular inferior para 6 variables.

¡Copiado!

1	DATA kinzer(type=corr);
2	title "Data Matrix of Kinzer & Kinzer, see GUTTMAN (1957)";
3	_type_ = 'corr';
4	INPUT _name_ $ var1-var6;
5	DATALINES;
6	var1 1.00 . . . . .
7	var2 .51 1.00 . . . .
8	var3 .46 .51 1.00 . . .
9	var4 .46 .47 .54 1.00 . .
10	var5 .40 .39 .49 .57 1.00 .
11	var6 .33 .39 .47 .45 .56 1.00
12	;

2 Bloque de código

PROC CALIS

Explicación :
Ejecución del procedimiento CALIS con la instrucción COSAN. Definición de la estructura del modelo, las matrices de parámetros (B, Psi, D) y aplicación de restricciones matemáticas específicas sobre los coeficientes a través de código SAS estándar dentro del procedimiento.

¡Copiado!

1	PROC CALIS DATA=Kinzer nobs=326 nose;
2	cosan
3	var= var1-var6,
4	D(6,DIA) * B(2,GEN) + D(6,DIA) * Psi(6,DIA);
5	matrix B
6	[ ,1] = b11 b21 b31 b41 b51 b61,
7	[ ,2] = b12 b22 b32 b42 b52 b62;
8	matrix Psi
9	[1,1] = psi1-psi6;
10	matrix D
11	[1,1] = d1-d6;
12	parameters alpha (1.);
13
14	/* SAS Programming Statements to Define Dependent Parameters*/
15	/* 6 constraints on the factor loadings */
16	b12 = alpha - b11;
17	b22 = alpha - b21;
18	b32 = alpha - b31;
19	b42 = alpha - b41;
20	b52 = alpha - b51;
21	b62 = alpha - b61;
22
23	/* 6 Constraints on Correlation structures */
24	psi1 = 1. - b11 * b11 - b12 * b12;
25	psi2 = 1. - b21 * b21 - b22 * b22;
26	psi3 = 1. - b31 * b31 - b32 * b32;
27	psi4 = 1. - b41 * b41 - b42 * b42;
28	psi5 = 1. - b51 * b51 - b52 * b52;
29	psi6 = 1. - b61 * b61 - b62 * b62;
30	vnames
31	D = [var1-var6],
32	B = [factor1 factor2],
33	Psi = D;
34	RUN;

Este material se proporciona "tal cual" por We Are Cas. No hay garantías, expresas o implícitas, en cuanto a la comerciabilidad o idoneidad para un propósito particular con respecto a los materiales o el código contenidos en este documento. We Are Cas no es responsable de los errores en este material tal como existe ahora o existirá, ni We Are Cas proporciona soporte técnico para el mismo.

Información de copyright : SAS SAMPLE LIBRARY

Documentación relacionada

Aucune documentation spécifique pour cette catégorie.