/******************************************************************************
 * Programme : Exemple de démarrage pour PROC VARIOGRAM
 * Reference : EXEMPL2533
 * Source    : https://www.wearecas.eu/en/sampleCode/EXEMPL2533
 ******************************************************************************/

/* --- BLOC 1 --- */
title 'Spatial Correlation Analysis with PROC VARIOGRAM';

ods graphics on;

/* Perform preliminary analysis --------------------------------*/

proc variogram data=sashelp.thick plots=pairs(thr=30);
   compute novariogram nhc=20;
   coordinates xc=East yc=North;
   var Thick;
run;

/* --- BLOC 2 --- */
/* Empirical SV (95% CL) ---------------------------------------*/

proc variogram data=sashelp.thick outv=outv;
   compute lagd=7 maxlag=10 cl robust;
   coordinates xc=East yc=North;
   var Thick;
run;

/* --- BLOC 3 --- */
proc variogram data=sashelp.thick outv=outv plots(only)=moran;
   compute lagd=7 maxlag=10 autocorr(assum=random);
   coordinates xc=East yc=North;
   var Thick;
run;

/* --- BLOC 4 --- */
/* Fit Gaussian model ------------------------------------------*/

proc variogram data=sashelp.thick outv=outv;
   store out=SemivStoreGau / label='Thickness Gaussian WLS Fit';
   compute lagd=7 maxlag=10;
   coordinates xc=East yc=North;
   model form=gau cl / covb;
   var Thick;
run;

ods graphics off;